time.coffee

((WIN) ->

  YEAR = "year"
  MONTH = "month"
  DAY = "day"
  HOUR = "hour"
  MINUTE = "minute"
  SECOND = "second"

  DEFAULT_FORMAT = "%y-%M-%d %h:%m:%s"

  map = 
    "%y": YEAR
    "%M": MONTH
    "%d": DAY
    "%h": HOUR
    "%m": MINUTE
    "%s": SECOND

  unify = (time) ->
    time -= 0
    time *= 1000 if "#{time}".length is 10
    time

  two = (str) ->
    s = "#{str}"
    s = "0#{s}" if s.length is 1
    s

  replace = (str, src, dst) ->
    reg = new RegExp src, "g"
    str.replace reg, dst

  getFullTime = (time) ->
    date = new Date(unify time)

    year: date.getFullYear()
    month: two (date.getMonth() + 1)
    day: two date.getDate()
    hour: two date.getHours()
    minute: two date.getMinutes()
    second: two date.getSeconds()


  time =

    default: (time, format) ->
      if format and (typeof format) isnt "string"
        throw new Error "format must be a string."

      fullTime = getFullTime time
      ret = format or DEFAULT_FORMAT

      for src of map
        ret = replace(ret, src, fullTime[map[src]])

      ret

    human: (time) ->
      time = unify time
      int = parseInt

      curTime = +new Date()
      diff = curTime - time
      ago = ""

      if 1000 * 60 > diff
        ago = "刚刚"
      else if 1000 * 60 <= diff and 1000 * 60 * 60 > diff
        ago = int(diff / (1000 * 60)) + "分钟前"
      else if 1000 * 60 * 60 <= diff and 1000 * 60 * 60 * 24 > diff
        ago = int(diff / (1000 * 60 * 60)) + "小时前"
      else if 1000 * 60 * 60 * 24 <= diff and 1000 * 60 * 60 * 24 * 30 > diff
        ago = int(diff / (1000 * 60 * 60 * 24)) + "天前"
      else if 1000 * 60 * 60 * 24 * 30 <= diff and 1000 * 60 * 60 * 24 * 30 * 12 > diff
        ago = int(diff / (1000 * 60 * 60 * 24 * 30)) + "月前"
      else
        ago = int(diff / (1000 * 60 * 60 * 24 * 30 * 12)) + "年前"
      
      ago

  entry = time.default
  entry.human = entry.ago = time.human

  if typeof module isnt "undefined" and module.exports
    module.exports = exports = entry

  else if typeof WIN["define"] is "function"
    define (require, exports, module) ->
      module.exports = exports = -> entry

  else if typeof WIN["angular"] is "object"
    angularApp = angular.module("binnng/time", [])

    angularApp.factory "$time", -> entry
    angularApp.filter "ago", -> (time) -> entry.ago time
    angularApp.filter "date", -> (time) -> entry time, "%y年%M月%d日"
    angularApp.filter "datetime", -> (time) -> entry time, DEFAULT_FORMAT

  else
    WIN["Time"] = entry


) window